10 REM SAM & ED CUSTOMIZER
20 REM COPYRIGHT 1987 - COMPUTE! PUBLICATIONS, INC. ALL RIGHTS RESERVED
30 POKE 53280,2:POKE 53281,12:BK=1
40 GOSUB 550
50 PRINT"CHANGE COLORS (Y/N)";:INPUT A$:IF A$<>"Y" THEN 230
60 PRINT"PRESS SPACEBAR TO CHOOSE COLORS"
70 PRINT"AND THEN PRESS RETURN TO SELECT"
80 PRINT"BORDER COLOR     ";:GOSUB 600
90 BD=X:POKE 53280,X
100 PRINT"BACKGROUND COLOR ";:GOSUB 600
110 BK=X:POKE 53281,X:IF BK=0 THEN POKE 646,1
120 PRINT"SAM'S BODY COLOR ";:GOSUB 600
130 SB=X
140 PRINT"SAM'S LEG COLOR  ";:GOSUB 600
150 SL=X
160 PRINT"ED'S BODY COLOR  ";:GOSUB 600
170 EB=X
180 PRINT"ED'S LEG COLOR   ";:GOSUB 600
190 EL=X
200 POKE 2431,BD:POKE 2441,BK
210 POKE 2461,SL:POKE 2466,SB
220 POKE 2471,EL:POKE 2476,EB
230 POKE 53280,2:POKE 53281,12:POKE 646,0
240 GOSUB 550:PRINT"CHANGE TIMER (Y/N)";:INPUT D$:IF D$="Y" THEN GOSUB 690
250 GOSUB 550:PRINT"CHANGE MESSAGES (Y/N)";:INPUT A$:IF A$<>"Y" THEN 450
260 GOSUB550
270 PRINT"UPCOMING EVENT #1 (37 CHARS MAX.)":INPUT A$
280 IF LEN(A$)<37 THEN A$=A$+" ":GOTO 280
290 A$=LEFT$(A$,37)
300 FOR Y=1 TO 37:NC=ASC(MID$(A$,Y,1)):IF NC>63 THEN NC=NC-64
310 POKE 2207+Y,NC
320 NEXT Y
330 PRINT"UPCOMING EVENT #2 (37 CHARS MAX.)":INPUT A$
340 IF LEN(A$)<38 THEN A$=A$+" ":GOTO 340
350 A$=LEFT$(A$,38)
360 FOR Y=1 TO 38:NC=ASC(MID$(A$,Y,1)):IF NC>63 THEN NC=NC-64
370 POKE 2245+Y,NC
380 NEXT Y
390 PRINT"UPCOMING EVENT #3 (29 CHARS MAX.)":INPUT A$
400 IF LEN(A$)<29 THEN A$=A$+" ":GOTO 400
410 A$=LEFT$(A$,29)
420 FOR Y=1 TO 29:NC=ASC(MID$(A$,Y,1)):IF NC>63 THEN NC=NC-64
430 POKE 2284+Y,NC
440 NEXT Y
450 PRINT"INSERT A NEW FORMATTED DISK":FOR D=1 TO 1000:NEXT
460 PRINT"  PRESS ANY KEY TO SAVE CUSTOM SAM & ED [146]"
470 GET DH$
480 IF DH$="" THEN 470
490 POKE 44,8:POKE 46,25
500 PRINT"JUST A MOMENT..."
510 PRINT"SAVING CUSTOM SAM & ED"
520 OPEN 1,8,15,"S0:CUSTOM SAM & ED":CLOSE 1
530 SAVE"CUSTOM SAM & ED",8
540 PRINT"[147]      PRESS RETURN TO PLAY SAM & ED     [146]":PRINT"RUN[145][145][145]":END
550 PRINT"[147][144]";:PRINTSPC(9)"  SAM & ED CUSTOMIZER  [146]"
560 FOR M=1 TO 10:PRINT"":NEXT
570 PRINTSPC(5)"[213][196][201] COPYRIGHT 1987"
580 PRINTSPC(5)"[199]C[200] COMPUTE! PUBLICATIONS INC."
590 PRINTSPC(5)"[202][198][203] ALL RIGHTS RESERVED":RETURN
600 FOR X=0 TO 15
610 POKE 646,X:PRINT" [146]";"[157]";:GET A$:IF A$=CHR$(13) THEN POKE 646,0:GOTO 670
620 IF A$=CHR$(32) THEN 640
630 GOTO 610
640 IF X=15 THEN 600
650 NEXT
660 GOTO 610
670 PRINT:IF BK=0 THEN POKE 646,1
680 RETURN
690 PRINT"ENTER A NUMBER LESS THAN 10";:INPUT H$
700 IF H$="" THEN 700
710 H=VAL(H$)+176
720 POKE 5714,176:POKE 5719,H:RETURN